易语言实现QQ登录

.版本 2
.支持库 spec
.支持库 internet
.支持库 dp1

.子程序 _编辑框_QQ帐号_列表项被选择
.局部变量 密码, 文本型

.如果真 (寻找文本 (帐号密码, 编辑框_QQ帐号.内容, 1, 假) ≠ -1)
密码 ＝ 文本_取出中间文本 (帐号密码, “&username=” ＋ 编辑框_QQ帐号.内容 ＋ “&password=”, #换行符)
编辑框_QQ密码.内容 ＝ 文本_解密 (密码, 编辑框_QQ帐号.内容 ＋ “123456789”)
是否需要验证码 (删首尾空 (编辑框_QQ帐号.内容))
.如果真结束

.子程序 _按钮_登录_被单击
.局部变量 QQ帐号, 文本型
.局部变量 QQ密码, 文本型
.局部变量 验证码, 文本型

QQ帐号 ＝ 删首尾空 (编辑框_QQ帐号.内容)
QQ密码 ＝ 编辑框_QQ密码.内容
验证码 ＝ 编辑框_验证码.内容
登录QQ空间 (QQ帐号, QQ密码, 验证码)

.子程序 登录QQ空间
.参数 QQ帐号, 文本型
.参数 QQ密码, 文本型
.参数 验证码, 文本型
.局部变量 登录地址, 文本型
.局部变量 登录返回, 文本型
.局部变量 读入文件, 字节集
.局部变量 保存值, 字节集

登录地址 ＝ “http://ptlogin2.qq.com/login?u=” ＋ QQ帐号 ＋ “&p=” ＋ QQ密码加密 (QQ密码, 验证码判断码, QQ密码加密值) ＋ “&verifycode=” ＋ 验证码 ＋ “&aid=549000912&u1=http%3A%2F%2Fqzs.qq.com%2Fqzone%2Fv5%2Floginsucc.html%3Fpara%3Dizone&h=1&ptredirect=0&ptlang=2052&from_ui=1&dumy=&low_login_enable=0®master=&fp=loginerroralert&action=16-57-1375238731962&mibao_css=&t=1&g=1&js_ver=10036&js_type=1&login_sig=6Nl0dpHM2EGOuS-5uxCZVZM9rSjLcg60hMZq5qsx2DDh526fhVs*5kozukn1mvyI”
登录返回 ＝ 编码_utf8到gb2312 (到文本 (网页_访问 (登录地址, 0, , , , , , , , , g_tk)))
g_tk ＝ 计算G_tk (g_tk)
.如果 (寻找文本 (登录返回, “登录成功！”, 1, 假) ≠ -1)
读入文件 ＝ 读入文件 (取运行目录 () ＋ “\Flash.is”)
.如果真 (寻找文本 (到文本 (读入文件), 删首尾空 (编辑框_QQ帐号.内容), , 假) ≠ -1)
文本_删除指定文本行 (到文本 (读入文件), 文本_取文本所在行 (到文本 (读入文件), 删首尾空 (编辑框_QQ帐号.内容), ))
.如果真结束
保存值 ＝ 到字节集 (“&username=” ＋ 删首尾空 (编辑框_QQ帐号.内容) ＋ “&password=” ＋ 文本_加密 (编辑框_QQ密码.内容, 删首尾空 (编辑框_QQ帐号.内容) ＋ “123456789”) ＋ #换行符)
.如果 (寻找文本 (到文本 (读入文件), 到文本 (保存值), , 假) ≠ -1)

.否则
写到文件 (取运行目录 () ＋ “\Flash.is”, 读入文件 ＋ 保存值)
.如果结束
编辑框_QQ帐号.禁止 ＝ 真
编辑框_QQ密码.禁止 ＝ 真
编辑框_验证码.禁止 ＝ 真
载入 (窗口1, , 假)
_启动窗口.可视 ＝ 假
.否则
信息框 (“登录失败！”, #信息图标, “ ”)
获取验证码 ()
.如果结束

.子程序 是否需要验证码
.参数 QQ帐号, 文本型
.局部变量 验证地址, 文本型
.局部变量 验证访问, 文本型

验证地址 ＝ “http://check.ptlogin2.qq.com/check?regmaster=&uin=” ＋ QQ帐号 ＋ “&appid=549000912&js_ver=10036&js_type=1&login_sig=6Nl0dpHM2EGOuS-5uxCZVZM9rSjLcg60hMZq5qsx2DDh526fhVs*5kozukn1mvyI&u1=http%3A%2F%2Fqzs.qq.com%2Fqzone%2Fv5%2Floginsucc.html%3Fpara%3Dizone&r=0.45562692366007007”
验证访问 ＝ 编码_utf8到gb2312 (到文本 (网页_访问 (验证地址, 0)))
验证码判断码 ＝ 文本_取出中间文本 (验证访问, “','”, “','”)
QQ密码加密值 ＝ “\” ＋ 文本_取出中间文本 (到文本 (验证访问), “','\”, “'”)
调试输出 (验证码判断码, QQ密码加密值)
.如果 (取文本长度 (验证码判断码) ≠ 4 且 编辑框_QQ帐号.内容 ≠ “”)
编辑框_验证码.禁止 ＝ 假
编辑框_QQ密码.内容 ＝ “”
编辑框_验证码.内容 ＝ “”
图片框1.禁止 ＝ 假
获取验证码 ()
.否则
编辑框_验证码.禁止 ＝ 真
编辑框_验证码.内容 ＝ 验证码判断码
图片框1.禁止 ＝ 真
图片框1.图片 ＝ 到字节集 (“”)
.如果结束

.子程序 获取验证码

.如果真 (编辑框_QQ帐号.内容 ≠ “”)
图片框1.图片 ＝ HTTP读文件 (“http://captcha.qq.com/getimage?uin=” ＋ 删首尾空 (编辑框_QQ帐号.内容) ＋ “&aid=549000912&0.5757994162771172”)
.如果真结束

.子程序 _图片框1_鼠标左键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

获取验证码 ()

.子程序 QQ密码加密, 文本型
.参数 密码, 文本型
.参数 验证码, 文本型
.参数 值1, 文本型
.局部变量 a, 字节集
.局部变量 b, 文本型
.局部变量 c, 文本型

a ＝ 字节集_还原 (取数据摘要 (到字节集 (密码)))
b ＝ 到大写 (取数据摘要 (a ＋ 字节集_还原 (子文本替换 (值1, “\x”, , , , 真))))
c ＝ 到大写 (取数据摘要 (到字节集 (b ＋ 验证码)))
返回 (c)

.子程序 _编辑框_QQ密码_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
_按钮_登录_被单击 ()
.如果真结束

.子程序 _编辑框_验证码_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
_按钮_登录_被单击 ()
.如果真结束

.子程序 _选择框1_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
_按钮_登录_被单击 ()
.如果真结束

.子程序 _按钮_登录_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
_按钮_登录_被单击 ()
.如果真结束

.子程序 _编辑框_QQ密码_获得焦点

是否需要验证码 (编辑框_QQ帐号.内容)

温馨提示：答案为网友推荐，仅供参考

当前网址：https://verywind.cn/ee/r737xfvrxrejyjf733.html