如题所述
.版本 2
.程序集 程序集1
.子程序 _启动子程序, 整数型, , 本子程序在程序启动后最先执行
载入 (窗口1, , 假)
返回 (0) ' 可以根据您的需要返回任意数值
.版本 2
.程序集 窗口程序集1
.程序集变量 配置文件名, 文本型
.程序集变量 分割符, 文本型
.子程序 _按钮关于_被单击
信息框 (“这个程序主要演示了用多文件对话框的方法” ＋ #换行符 ＋ “数组的简单应用” ＋ #换行符 ＋ “文本操作支持库的简单应用” ＋ #换行符 ＋ “信息框的简单应用” ＋ #换行符 ＋ “读写配置项的应用” ＋ #换行符 ＋ “风格制作____QQ:1194147077”, 0 ＋ #信息图标, “例程简介”)
.子程序 _按钮打开_被单击, , , 打开
.局部变量 文件名数组, 文本型, , "0"
.局部变量 文件总数, 整数型
.局部变量 计次, 整数型
文件名数组 ＝ 多文件对话框 (“选择多个文件”, “mp3文件|*.mp3;*.MP3|wav文件|*.wav|txt文件|*.txt;*.TXT”, , 取运行目录 (), ) ' 显示一个文件打开对话框，允许用户选择或输入多个所需要打开的已存在文件，返回用户所选择或输入后的结果文本数组。如果用户未输入或按“取消”按钮退出，则返回一个成员数为0的空文本数组。本命令为初级命令。
' 这里返回的是一个文本型的数组，所以变量一定要配套
文件总数 ＝ 取数组成员数 (文件名数组) ' 看看有多少个路径
.如果真 (文件总数 ≠ 0) ' 不等于零表示选择了文件，并且按下了确定
.计次循环首 (文件总数, 计次)
列表框1.加入项目 (文件名数组 [计次], ) ' 这个命令应该很好理解吧。。
.计次循环尾 ()
信息框 (“已加入列表框，本次总共加入” ＋ 到文本 (文件总数) ＋ “个文件”, 0 ＋ #信息图标, “提示”)
.如果真结束
.子程序 _按钮删除_被单击
.判断开始 (列表框1.现行选中项 ≠ -1) ' 判断跟如果基本是一个东西，不过判断的条例比较清晰，所以我用判断
.如果真 (信息框 (“你确定要删除” ＋ 列表框1.取项目文本 (列表框1.现行选中项), 4 ＋ #警告图标, “警告”) ＝ 5) ' 因为按下是的时候返回的是5 按下取消的时候返回的是6，这里只用到5，所以6的没写
列表框1.删除项目 (列表框1.现行选中项)
信息框 (“删除成功”, 0 ＋ #信息图标, “信息”) ' 因为是演示用的所以本程序用的信息框比较多，是为了让你看的更清楚，实际应用中不用这么繁琐
.如果真结束
.默认
信息框 (“您未选择文件，请先选择一个文件”, 0 ＋ #信息图标, “信息”)
.判断结束
.子程序 _按钮清空_被单击
.判断开始 (列表框1.取项目数 () ≠ 0) ' 看看列表框是不是空的，实际应用中一般都是列表框一空，删除按钮就禁止掉了
.如果真 (信息框 (“确定清空？”, 4 ＋ #警告图标, “警告”) ＝ 5) ' 因为按下是的时候返回的是5 按下取消的时候返回的是6，这里只用到5，所以6的没写
列表框1.清空 ()
信息框 (“清空成功”, 0 ＋ #信息图标, “信息”)
.如果真结束
.默认
信息框 (“您的列表未添加项目”, 0 ＋ #信息图标, “信息”)
.判断结束
.子程序 _按钮保存_被单击
.局部变量 计次, 整数型
.局部变量 临时文件名数组, 文本型, , "0"
.局部变量 原配置, 文本型
.判断开始 (列表框1.取项目数 () ≠ 0) ' 看看列表框是不是空的，实际应用中一般都是列表框一空，删除按钮就禁止掉了
写配置项 (配置文件名, “列表数据”, “项目”, “”) ' 先把原来的配置清空掉
.计次循环首 (列表框1.取项目数 (), 计次)
原配置 ＝ 读配置项 (配置文件名, “列表数据”, “项目”, )
.判断开始 (原配置 ＝ “”) ' 判断是不是第一个写到的项目，为了以后分割文本方便
写配置项 (配置文件名, “列表数据”, “项目”, 列表框1.取项目文本 (计次 － 1)) ' 计次-1是因为列表框的第一个项目索引是0
.默认
写配置项 (配置文件名, “列表数据”, “项目”, 原配置 ＋ 分割符 ＋ 列表框1.取项目文本 (计次 － 1)) ' “||||”这个符号是为了分割文本
.判断结束
.计次循环尾 ()
.默认
信息框 (“您的列表未添加项目”, 0 ＋ #信息图标, “信息”)
.判断结束
.子程序 _窗口1_创建完毕
配置文件名 ＝ 取运行目录 () ＋ “\配置文件.ini”
分割符 ＝ “||||”
.子程序 _按钮读入_被单击
.局部变量 配置, 文本型
.局部变量 文件名数组, 文本型, , "0"
.局部变量 计次, 整数型
配置 ＝ 读配置项 (配置文件名, “列表数据”, “项目”, “”)
.判断开始 (配置 ≠ “”) ' 等于空代表原来是空的
列表框1.清空 ()
.判断开始 (寻找文本 (配置, 分割符, , 假) ≠ -1) ' 不等于-1代表换行符存在，也就是有两个或两个以上的配置项
文件名数组 ＝ 分割文本 (配置, 分割符, )
.计次循环首 (取数组成员数 (文件名数组), 计次)
列表框1.加入项目 (文件名数组 [计次], )
.计次循环尾 ()
.默认
列表框1.加入项目 (配置, ) ' 只有一个的时候用分割文本会出错，所以直接添加进去
.判断结束
.默认
信息框 (“您的列表未添加项目”, 0 ＋ #信息图标, “信息”)
.判断结束
