如何用vb保存修改过的颜色？最好对初学者适用的解决方法

您好，关于你这个问题我实在不知道你的具体程序是什么样子的。所以，与其我写出一个代码来，不如教你如何写这种程序。

1、在电脑里，颜色是用R、G、B三色组合而成。而在VB下，颜色是以Long类型整数表示的。
一个颜色的RGB值你可以用Windows下的“画笔”取得。而知道一个颜色的RGB值之后，可以用RGB函数获取它的Long类型颜色值。
所谓的：CD1.ShowColor、Frame1.BackColor这些值，其实都是Long类型整数。

以下程序用来以数组保存10种颜色的数组。
Dim tColors() As Long
ReDim tColors(9)
tColors(0)=RGB(0,0,0) '黑色
tColors(1)=RGB(255,255,255) '白色
tColors(2)=RGB(128,128,128) '深灰色
tColors(3)=RGB(192,192,192) '浅灰色
tColors(4)=RGB(255,0,0) '亮红色
tColors(5)=RGB(0,255,0) '亮绿色
tColors(6)=RGB(255,128,0) '亮橙色
tColors(7)=RGB(192,200,255) '淡蓝色
tColors(8)=RGB(255,255,0) '亮黄色
tColors(9)=RGB(128,64,0) '棕色

只要把你的控件颜色对应数组里的一个元素就可以了。
比如：
Frame1.BackColor=tColors(0)
Frame2.BackColor=tColors(1)

2、保存数组到文件。
Dim tColors() As Long
ReDim tColors(x) 'x是你的数组元素数量。
Open "Color.bin" For Binary As #1
Put #1,1,tColors()
Close #1

3、读取数组。
Dim tColors() As Long
ReDim tColors(x) 'x是你的数组元素数量
Open "Color.bin" For Binary As #1
Get #1,1,tColors()
Close #1

只要你灵活运用读写数组和以数组保存颜色的方法，相信你一定能写出这种程序来。

给你写了一个例子：

Private priColors() As Long

Private Sub Command1_Click()
'选择背景颜色按钮
With CommonDialog1
.ShowColor
priColors(0) = .Color
End With
AppColor
End Sub
Private Sub Command2_Click()
'选择前景颜色按钮
With CommonDialog1
.ShowColor
priColors(1) = .Color
End With
AppColor
End Sub

Private Sub Command3_Click()
'储存颜色按钮
SaveColor
End Sub

Private Sub Command4_Click()
'读取颜色按钮
LoadColor
AppColor
End Sub

Private Sub Form_Load()
ReDim priColors(1)
LoadColor
If priColors(0) = priColors(1) Then
priColors(0) = RGB(215, 215, 215)
priColors(1) = RGB(0, 0, 0)
End If
AppColor
End Sub

Private Sub SaveColor()
'保存颜色
Open "Colors.bin" For Binary As #1
Put #1, 1, priColors()
Close #1
End Sub

Private Sub LoadColor()
'读取颜色
Open "Colors.bin" For Binary As #1
Get #1, 1, priColors()
Close #1
End Sub

Private Sub AppColor()
'应用颜色
ObjAppColor Frame1: ObjAppColor Frame2: ObjAppColor Frame3
ObjAppColor Label1: ObjAppColor Label2: ObjAppColor Label3
ObjAppColor Form1
End Sub

Private Sub ObjAppColor(ByRef pObject As Object)
'应用颜色到单个对象
pObject.BackColor = priColors(0)
pObject.ForeColor = priColors(1)
End Sub

温馨提示：答案为网友推荐，仅供参考

当前网址：https://verywind.cn/ee/vjeeey2yx.html